Typeset unbalanced brackets

Question

In LaTeX, you can typeset expressions containing unbalanced brackets, by balancing them with an invisible delimiter \left. or \right.. Some such notations are common in calculus; for example, the two common notations for applying an expression at two points:

$$\int_a^b x^2 \mathrm{d} x = \left. \frac{x^3}{3} \right]_a^b \equiv \left. \frac{x^3}{3} \right|_a^b $$

Applying a function at one point:

$$\left. \frac{\partial f}{\partial x} \right| _{x=0}$$

The alternative notation for an open interval endpoint:

$$\left[a,b\right) \equiv \left[a, b\right[$$

But in the Mathematica symbol list, I don't see any invisible brackets. If you simply leave out the delimiter, it results in an unmatched bracket, messing up the formatting if you have multiple such expressions in the same cell.

How do you typeset such expressions in Mathematica? (This is in display formulas; it doesn't have to be evaluatable.)

Answer 1

See this answer to question (101070) for the basic approach to enable the typesetting you desire for evaluating a function at one or two points. The interval typesetting is a bit trickier, but the basic idea is to give the bracket a SyntaxForm option. As a simple example, compare:

RawBoxes @ RowBox[{"[", FractionBox["x","3"], "["}]

with:

RawBoxes @ RowBox[{"[", FractionBox["x","3"], TagBox["[", #&, SyntaxForm->"]"]}]

The latter example shows the desired spanning behavior. Of course, it is not evaluatable. To make it evaluatable, one can use a TemplateBox. Here is an input alias making use of a TemplateBox:

CurrentValue[EvaluationNotebook[], {InputAliases, "oc"}] = TemplateBox[
    {"\[SelectionPlaceholder]"},
    "OCInterval",
    DisplayFunction -> (
        RowBox[{
            StyleBox["[", SpanMaxSize->Infinity],
            #,
            StyleBox[TagBox["[", #&, SyntaxForm->"]"], SpanMaxSize->Infinity]
        }]&
    )
];

Here is an animation showing the alias in action:

Answer 2

If the problem is the size of the brackets after e.g. g[x] then you can split the inline cells. See before and after shots below

Just to be clear, the second example in the screen grab is two inline cells side by side:

Answer 3

If I understood the question, this is a question on the automatic formatting of an expression you are trying to type in, on how the FE automatically groups it into boxes.

So, for example

RawBoxes@SubscriptBox[
  RowBox[{RowBox[{SubscriptBox[
       RowBox[{RowBox[{"f", "(", FractionBox["x", "6"], ")"}], "]"}], 
       RowBox[{"x", "=", "1"}]], "=", RowBox[{"g", "[", "x", "]"}]}], 
    "]"}], RowBox[{"x", "=", "1"}]]

is not the same as this

RawBoxes@RowBox[{SubscriptBox[
    RowBox[{RowBox[{"f", "(", FractionBox["x", "6"], ")"}], "]"}], 
    RowBox[{"x", "=", "1"}]], "=", 
   SubscriptBox[RowBox[{RowBox[{"g", "(", "x", ")"}], "]"}], 
    RowBox[{"x", "=", "1"}]]}]

In those cases where the automatic grouping isn't appropriate, I don't see an easy fix so far to fix it without interrupting the typing flow.

An input alias such as the following would allow you to insert the desired box structure. The invisible TagBox is important so that the front end doesn't regroup automatically

PrependTo[CurrentValue[InputNotebook[], InputAliases], 
 "app2p" -> 
  TagBox[RowBox[{"\[SelectionPlaceholder]", 
     SubsuperscriptBox["]", "\[Placeholder]", "\[Placeholder]"]}], 
   "app2p"]]

As all input aliases, it works by typing the keyword between Esc. In this case, the keyword is app2p

A more general solution of this sort is to define an input alias to insert only the invisible tag box

   PrependTo[CurrentValue[InputNotebook[], InputAliases], 
     "tb" ->  TagBox["\[SelectionPlaceholder]", "tb"]]

You just have to remember that there's an invisible box and exit it when appropriate

Answer 4

I don't get the described problems when using inline math in a text cell (using Ctrl-(), nor when I copy this math to an empty space. I get this: