How to find the three largest values among cells in different columns in Excel in Portuguese?

Question

I'm trying to calculate the three largest values among cells that are distributed across different columns in Excel, using the Portuguese version of the software. The cells I want to compare are in different columns (for example, C17, F17, I17, and L17).

I tried using the "LARGER" function, but I'm struggling to get it to work correctly for cells in distinct columns. Is there an efficient way to find the three largest values among these cells?

I appreciate any suggestions or solutions to solve this problem.

=MÁXIMO(MAIOR(C17,F17,I17,L17,1),MAIOR(C17,F17,I17,L17,2),MAIOR(C17,F17,I17,L17,3))

I tried using the 'LARGE' function in Excel to find the three largest values among cells in different columns. I expected the function to return the three largest values correctly, but it didn't work as expected. Instead, I received an error message or incorrect results. I'm looking for an alternative solution or a correction to my approach to accurately identify the three largest values among cells in different columns

Answer 1

Try using the following formula:

---

=LARGE(HSTACK(C17,F17,I17,L17),{1,2,3})

---

• In Portuguese Excel Version will be:

=MAIOR(HSTACK(C17;F17;I17;L17);{1.2.3})

---

• Or can use TOCOL() as well:

=MAIOR(TOCOL((C17;F17;I17;L17);1);{1;2;3})

---

=LARGE(TOCOL((C17,F17,I17,L17)),{1,2,3})

---

• For Older Versions could try using INDEX()+MATCH()

=LARGE(INDEX(C17:L17,,{1,4,7,10}),{1,2,3})

---

• In Portuguese Excel Version will be:

=MAIOR(ÍNDICE(C17:L17;;{1.4.7.10});{1.2.3})

---

• One another alternative is to use AGGREGATE() function:

=AGGREGATE(14,7,HSTACK(C17,F17,I17,L17),{1,2,3})

---

=AGREGAR(14;7;HSTACK(C17;F17;I17;L17);{1.2.3})

---

_{NOTE: Older Versions Of Excel may need to hit CTRL+SHIFT+ENTER while exiting the edit mode, however this depends on the versions of Excel.}

---